Apple Mail nutzt glaube ich seit Leopard nicht mehr eine fette mbox Datei sondern einzelne .emlx Dateien zum speichern der abgerufenen Emails. So können die Dateien schön einzeln indiziert (Spotlight) werden und können auch recht leicht kopiert werden (TimeMachine). Eine solche EMLX-Datei lässt sich über Quicklook oder Apple Mail betrachten und beinhaltet sogar die in der Email enthaltenen Anhänge.Dummerweise kann man via AppleScript nicht direkt den Speicherort der Email abfragen, aber da die emlx-Datei nach der ID der Email benannt ist, kann man sie recht leicht im entsprechenden Account-Ordner finden.
Das tut dieses Skript also, es sucht sich die emlx-Dateien der ausgewählten Emails kopiert diese auf den Schreibtisch…
Ein Grund für den regen Gebrauch von Wildcards im find-Befehl ist die Tatsache, dass besonder große Emails aufgesplittet werden in .emlx und .emlxpart Dateien. Gemeinsamer Nenner ist aber immer die ID, mit der der Dateiname stets beginnt.

--hubionmac.com 29.12.2010 EMLX-Dateien ausgewählter Emails in einen Order (Saved_Mails(Acountname) auf dem Schreibtisch kopieren... (4 Chris_Zuerich) 
-- hubionmac.com 17.03.2012 Nun bereiten wohl auch lokale Email-Ordner dem Skript kein Kopfzerbrechen mehr 
--auswahl aus Apple Mail abfragen 
set mymails to my getSelection() 
repeat with mymail in mymails 
   tell application "Mail" 
      --das Verzeichnis des Email Accounts ausfindig machen 
      try 
         set accountDir to quoted form of POSIX path of ((account directory of account of mailbox of mymail) as alias) 
      on error --ist wohl ein lokaler Mail-Ordner 
         set accountDir to "~/Library/Mail/" 
      end try 
      try 
         set account_name to (name of account of mailbox of mymail) as rich text 
      on error --ist wohl ein lokaler Mail-Ordner 
         set account_name to address of to recipient 1 of mymail 
         repeat with a in every account 
            if email addresses of a contains account_name then 
               set account_name to name of a 
               exit repeat 
            end if 
         end repeat 
      end try 
      tell application "Finder" to set temp_dir to quoted form of (POSIX path of (desktop as alias) & "Saved_Mails (" & account_name & ")/") 
      try 
         do shell script "mkdir " & temp_dir 
      end try 
      --in dem Account-Verzeichnis nach der der Email-Datei suchen und diese kopieren... 
      set myid to id of mymail 
      do shell script "find " & accountDir & " -name " & myid & "*.emlx* -exec cp {} " & temp_dir & " \\;" 
   end tell 
end repeat 

on getSelection() 
   tell application "Mail" 
      set a to selection 
      if (count of a) < 1 then 
         error "Eine Mitteilung muss ausgewählt sein." 
      end if 
      return a 
   end tell 
end getSelection
									

28.11.2012/13.05.2013: Leicht angepasste Version, die das Empfangsdatum und den Betreff mit in den Dateinamen der emlx-Datei schreibt:

--hubionmac.com 13.05.2013 kleiner BugFix... hatte vergessen temp_dir zu quoten ;-)
--hubionmac.com 29.12.2010 EMLX-Dateien ausgewählter Emails in einen Order (Saved_Mails(Acountname) auf dem Schreibtisch kopieren... (4 Chris_Zuerich) 
-- hubionmac.com 17.03.2012 Nun bereiten wohl auch lokale Email-Ordner dem Skript kein Kopfzerbrechen mehr 
--auswahl aus Apple Mail abfragen 
set mymails to my getSelection()
repeat with mymail in mymails
  tell application "Mail"
    set thesubject to subject of mymail
    set thesubject to my replace_chars(thesubject, "/", "-")
    set thesubject to my replace_chars(thesubject, ":", "-")
    set thedate to date received of mymail
    set thedate to (year of thedate) & "-" & (month of thedate as integer) & "-" & (day of thedate) as rich text
    --das Verzeichnis des Email Accounts ausfindig machen 
    try
      set accountDir to quoted form of POSIX path of ((account directory of account of mailbox of mymail) as alias)
    on error --ist wohl ein lokaler Mail-Ordner 
      set accountDir to "~/Library/Mail/"
    end try
    try
      set account_name to (name of account of mailbox of mymail) as rich text
    on error --ist wohl ein lokaler Mail-Ordner 
      set account_name to address of to recipient 1 of mymail
      repeat with a in every account
        if email addresses of a contains account_name then
          set account_name to name of a
          exit repeat
        end if
      end repeat
    end try
    tell application "Finder" to set temp_dir to (POSIX path of (desktop as alias) & "Saved_Mails (" & account_name & ")/.tmp/")
    try
      do shell script "mkdir -p " & quoted form of temp_dir
    end try
    --in dem Account-Verzeichnis nach der der Email-Datei suchen und diese kopieren... 
    set myid to id of mymail
    do shell script "find " & accountDir & " -name " & myid & "*.emlx* -exec cp {} " & quoted form of temp_dir & " \\;"
  end tell
  tell application "Finder"
    set thefiles to every item of (((temp_dir as POSIX file) as string) as alias)
    repeat with thefile in thefiles
      set name of thefile to (thedate & " - " & thesubject & " " & (name of thefile) as string)
    end repeat
    do shell script "cd " & quoted form of temp_dir & "; mv ./* ../"
  end tell
end repeat

on getSelection()
  tell application "Mail"
    set a to selection
    if (count of a) < 1 then
      error "Eine Mitteilung muss ausgewählt sein."
    end if
    return a
  end tell
end getSelection

on replace_chars(this_text, search_string, replacement_string)
  if this_text contains the search_string then
    set od to AppleScript's text item delimiters
    set AppleScript's text item delimiters to the search_string
    set the item_list to every text item of this_text
    set AppleScript's text item delimiters to the replacement_string
    set this_text to the item_list as string
    set AppleScript's text item delimiters to od
  end if
  return this_text
end replace_chars