Willkommen auf der Blog-Seite von hubionmac.com!
Alles rund um AppleScript und was mich sonst noch so interessiert ;-)!

Ich hatte ein paar defekte MP3-Dateien, die von einer Naim-Audio Station kopiert hatte. Diese Dateien ließen sich zwar über Quicktime abspielen, aber nicht in iTunes importieren. Auch die Vorschau unter OSX spielte die Titel zwar ab, zeigte aber u.a. das hinterlegte Album-Cover nicht an. Unter OSX ist das reparieren von beschädigten mp3-Dateien mit kostenpflichtigen Lösungen sicher möglich, nur nach einer leicht zu nutzenden und vor allen Dingen kostenfreien Lösung sucht man vergebens. Anders unter Windows oder Linux, wo u.a. MP3 Diags wahre Wunder wirkt.

Ich habe aber noch ein andere Tool gefunden, Quelloffen, klein und einfach zu kompilieren. mp3val lässt sich auch einfach in ein AppleScript implementieren uns so ist dieses Droplet entstanden mit dem sich defekte mp3-Dateien (Fehler mpeg-stream) einfach reparieren lassen.

mp3val 1.0

Continue reading...


Kleines Skript, welches einen einstellbaren Ordner in iTunes importiert und im Anschluss die iTunes Mediatheak auch von nicht mehr vorhandenen Tracks bereinigt.

try
  set defaultFolder to my decode_octal(do shell script "defaults read com.hubionmac.syncfolder2itunes defaultFolder")
  display alert "Change default folder?" & return & return & defaultFolder buttons {"Change", "no changes"} default button {"no changes"} giving up after 2
  if (button returned of the result) as text = "Change" then
    error
  end if
on error
  set defaultFolder to POSIX path of (choose folder)
  do shell script "defaults write com.hubionmac.syncfolder2itunes defaultFolder " & quoted form of defaultFolder
end try
set thefolder to (POSIX file defaultFolder) as alias

with timeout of 99999 seconds
  tell application "iTunes"
    --add thefolder to library
    add thefolder to playlist 1 of source 1
  end tell
end timeout
my remove_missing()

display notification "Done"
on remove_missing()
  tell application "iTunes"
    set the stored_setting to fixed indexing
    set fixed indexing to true
    set sourcename to name of source 1
    tell source sourcename
      set libname to name of playlist 1
      tell playlist libname
        repeat with i from the (count of tracks) to 1 by -1
          try
            if the location of track i is missing value then
              delete track i
              set the remove_counter to the remove_counter + 1
            end if
          end try
        end repeat
      end tell
    end tell
    set fixed indexing to the stored_setting
  end tell
end remove_missing

on decode_octal(str)
  set str to quoted form of str
  set cmd to quoted form of "#!/usr/bin/python 
import sys 

x = sys.argv[1] 
x = x.decode('unicode_escape' ) 
x=x.encode('utf-8') 
print x"
  set cmd_full to "python -c " & cmd & " " & str
  set r to do shell script cmd_full
  return r
end decode_octal

Continue reading...

Meine Schwester hat 1 GB Mailspace und muss in regelmäßigen Abständen die Emails aus der Inbox oder dem gesendet-Ordner in einen lokalen Mail-Ordner verschieben, damit das Postfach nicht überläuft.
Dieses Skript hier fragt den Quell-Account und das Quell-Postfach ab, im Anschluss das Zielpostfach und dann wie alt die Mails sein müssen, damit sie verschoben werden sollen.
Neben dem reinen Nutzen ein schönes Beispiel, wie man eine Mailbox via AppleScript-Dialog auswählen kann. ;-) Viel Spaß damit!

## MoveMail oder than... ©hubionmac.com 23.09.2014
## This script moves all Emails older than x days from a source mailbox to a destination mailbox
## source and destination mailbox may be located on differenc accounts or may be local mailboxes

tell application "Mail"
  set theaccounts to name of every account whose enabled is true
  set sourceAccount to (choose from list theaccounts & {"• Local •"} with prompt "Set Source-Mailbox:" & return & "Select Account") as string
  if sourceAccount is "false" then
    error number -128
  end if
  set sourceMailbox to (choose from list my return_mailboxes(sourceAccount) with prompt "Set Source-Mailbox:" & return & "Select Mailbox") as string
  if sourceMailbox is "false" then
    error number -128
  end if
  if sourceAccount is "• Local •" then
    set sourceMailbox to mailbox sourceMailbox
  else
    set sourceMailbox to mailbox sourceMailbox of account sourceAccount
  end if

  set destiAccount to (choose from list theaccounts & {"• Local •"} with prompt "Set destination-Mailbox:" & return & "Select Account" default items {sourceAccount}) as string
  if destiAccount is "false" then
    error number -128
  end if
  set destiMailbox to (choose from list my return_mailboxes(destiAccount) with prompt "Set destination-Mailbox:" & return & "Select Mailbox") as string
  if destiMailbox is "false" then
    error number -128
  end if
  if destiAccount is "• Local •" then
    set sourceMailbox to mailbox destiMailbox
  else
    set destiMailbox to mailbox destiMailbox of account destiAccount
  end if

  repeat until 1 = 0
    try
      set daycount to text returned of (display dialog "Only move mail older than x days" default answer "30") as integer
      if daycount > 0 then
        exit repeat
      end if
    end try
  end repeat
  set deadline to current date
  set deadline to deadline - 60 * 60 * 24 * daycount
  display dialog "Really move " & (count of (every message of sourceMailbox whose date sent < deadline)) & " messages?"
  move (every message of sourceMailbox whose date sent < deadline) to destiMailbox

end tell

on return_mailboxes(accountname)
  tell application "Mail"
    set l to {}
    if accountname is "• Local •" then
      repeat with thebox in every mailbox
        set tmp to name of thebox
        repeat until 1 is 0
          if name of container of thebox is not missing value then
            set tmp to name of container of thebox & "/" & tmp
            set thebox to container of thebox
          else
            exit repeat
          end if
        end repeat
        set l to l & {tmp as rich text}
      end repeat

    else
      repeat with thebox in every mailbox of account accountname
        set tmp to name of thebox
        repeat until 1 is 0
          if name of container of thebox is not missing value then
            set tmp to name of container of thebox & "/" & tmp
            set thebox to container of thebox
          else
            exit repeat
          end if
        end repeat
        set l to l & {tmp as rich text}
      end repeat
    end if
  end tell
  return l
end return_mailboxes

Continue reading...

In bestimmten Fällen möchten Unternehmen und Bildungseinrichtungen ihre Geräte möglicherweise mithilfe von iTunes aktivieren, ohne dass zusätzliche Inhalte synchronisiert oder gesichert werden. In diesem Artikel wird beschrieben, wie der Modus “Nur aktivieren” eingeschaltet wird.

Nun das schreibt Apple hier. Aber wer möchte schon immer diese Modus in iTunes aktiviert haben? Dieses Skript aktiviert den Modus solange es als Anwendung gespeichert (mit der Option “Nach Run-Handler anzeigen”)wurde, wenn man das Skript startet. Und deaktiviert die Einstellung sobald es wieder geschlossen wird.
iTunes wird von dem Skript automatisch neu gestartet, so dass die geänderte Einstellung direkt wieder aktiv wird.

### 11.09.2014 © hubionmac.com
### Applescript um iTunes in den StoreActivation Mode zu versetzten
### Damit wird jedes angeschlossene iOS Device direkt über iTunes aktiviert und wieder ausgeworfen
### Damit man iTunes normal weiter nutzen kann, ist dieses Setting nur solange aktiv, wie dieses Skript läuft (Als Anwendung gespeichert)

property setprefs : false

on run
  set theaction to button returned of (display alert "Activate StoreActivation Setting in iTunes? iTunes will restart?" buttons {"Activate", "nope quit"} default button {"Activate"})
  if theaction is "Activate" then
    tell application "System Events"
      repeat with i from 1 to 10
        if name of every process contains "iTunes" then
          tell application "iTunes" to quit
        else
          do shell script "defaults write com.apple.iTunes StoreActivationMode -integer 1"
          set setprefs to true
          exit repeat
        end if
        delay 1
      end repeat
      if setprefs is false then
        display alert "Error on resetting preferences... (could not quit iTunes in time) Restart and quit app to fix this"
      else
        tell application "iTunes" to activate
        do shell script "afplay /System/Library/Sounds/Pop.aiff "
      end if

    end tell
  else
    tell me to quit
  end if
end run

##Routine die beim Beendetn des Skript-Programmes durchlaufen wird
on quit
  ##es wird versucht die gesetzte Voreinstellung wieder zur löschen… kommt es zu einem Fehler, wird dieser angezeigt und das Programm beendet sich trotzdem...
  tell application "System Events"
    repeat with i from 1 to 10
      if name of every process contains "iTunes" then
        tell application "iTunes" to quit
      else
        do shell script "defaults write com.apple.iTunes StoreActivationMode -integer 0"
        set setprefs to false
        exit repeat
      end if
      delay 1
    end repeat
  end tell
  if setprefs is true then
    display alert "Error on resetting preferences... (could not quit iTunes in time) Restart and quit app to fix this"
  else
    tell application "iTunes" to activate
    do shell script "afplay /System/Library/Sounds/Pop.aiff "
  end if

  continue quit

end quit

Continue reading...

Im Zuge einer Projektarbeit (Aufsetzten eines OSX Update-Servers) musste ein Skirpt her, mit dem man kurzfristig die Adressen des lokalen Updates-Servers eintragen lassen kann. Das ist an sich nicht schwierig und lässt sich auch über einen Terminal-Befehl leicht erreichen. Das ganze soll nur möglichst einfach ablaufen und sich auch Rückgängig machen lassen, damit der lokale Update-Server nur verwendet wird, wenn das Programm auch läuft… also:

Das Skript hier einfach als Anwendung speicher, die nach dem Öffnen auch offen bleibt. Der Wert der Variable myupdate_server_ip sollte natürlich entsprechende IP des Update-Server gesetzte werden.

### 09.02.2014 © hubionmac.com
### AppleScript welches den Update-Server eines Macs für die Dauer der Laufzeit verändert und beim Beendet wieder auf den Default-Wert zurücksetzt
### Der Defaults Befehlt stammt von http://support.apple.com/kb/ht4069

##Voreinstellung, das ist die IP oder der Domain-Name des Update-Servers
property myupdate_server_ip : "192.168.1.1"

on run
  ##Wenn der Dialog mit Ja bestätigt wird geht es weiter, ansonsten beendet sich das Programm
  set doit to button returned of (display alert "Soll ich den Update-Server (" & myupdate_server_ip & ") eintragen?" buttons {"Nein", "Ja"} default button {"Ja"}) as text
  if doit is "Ja" then
    try
      ##das ist die eigentliche Code Zeile über die der Update-Server definiert wird
      do shell script "defaults write /Library/Preferences/com.apple.SoftwareUpdate CatalogURL http://" & myupdate_server_ip & ":8088/index.sucatalog" with administrator privileges
      ##Sofern der vorherige Eintrage erfolgreich war, müsste diese Befehl ohne Fehler durchlaufen
      do shell script "defaults read /Library/Preferences/com.apple.SoftwareUpdate CatalogURL"
      ##Das ist ein reiner Info Dialog ohne weitere Funktion… verschwindet nach 5 Sekunden
      display alert "Update Server eingetragen, beende das Programm, um den Eintrag wieder zu löschen…" buttons {"OK"} default button {"OK"} giving up after 5
    on error msg
      ##Sollte es einen Fehler gegegeben haben (z.B. die Voreinstellung wurde nicht gesetzt, wird dieser angezeigt und das Programm beendet...
      display alert "Es scheint ein Problem setzen der Voreinstellung gegeben zu haben…\n\n" & msg
      quit
    end try
  else
    ##Wenn der Anfangs-Dialog mit nein bestätigt wurde, beendet sich das Programm halt...
    tell me to quit
  end if

end run

##Routine die beim Beendetn des Skript-Programmes durchlaufen wird
on quit
  ##es wird versucht die gesetzte Voreinstellung wieder zur löschen… kommt es zu einem Fehler, wird dieser angezeigt und das Programm beendet sich trotzdem...
  try
    do shell script "sudo defaults delete /Library/Preferences/com.apple.SoftwareUpdate CatalogURL" with administrator privileges
    display alert "Update-Server wieder zurück auf default" giving up after 5
  on error msg
    display alert msg
  end try
  continue quit

end quit

Und sobald das Programm nun läuft, wir nach dem Kennwort gefragt, der Update-Server umgestellt und wenn man es beendet ist alles wieder auf Anfang gesetzt. Ist super praktisch, wenn man nur zeitweise den lokalen Update-Server nutzen möchte, z.B. bei mobilen Geräten, die nicht immer im lokalen Netzwerk verbleiben. Danke an Dennis für die Grund-Idee.

Continue reading...