hubionmac.com

--14.09.2011 hubionmac.com

-- parts of numbers selection code by http://hints.macworld.com/article.php?story=20090109055630154

-- requested @https://discussions.apple.com/thread/3325583?tstart=0

-- this script takes the value of a selection in numbers first and a asks for a folder

-- then the values of the first column of the selection are taken and all filenames of start start with that folder and are found in the defined folder will be

-- writen to the last column of the selection ----> you will have to select at least 2 columns

set thefolder to quoted form of POSIX path of ((choose folder) as alias)

tell application "Numbers"

activate

tell document 1

-- DETERMINE THE CURRENT SHEET

set current_sheet_index to 0

repeat with i from 1 to the count of sheets

tell sheet i

set x to the count of (tables whose selection range is not missing value)

end tell

if x is not 0 then

set the current_sheet_index to i

exit repeat

end if

end repeat

if the current_sheet_index is 0 then error "No sheet has a selected table."

-- GET THE VALUES OF THE SELECTED CELLS

tell sheet current_sheet_index

set the current_table to the first table whose selection range is not missing value

tell the current_table

set range_column_count to count of every column of selection range

set this_rows_first_cell_index to 1

set this_rows_last_cell_index to range_column_count

-- THIS CHANGES THE VALUE OF 

repeat with i from 2 to count of every cell of selection range

set thename to value of cell this_rows_first_cell_index of selection range

set foundfilenames to my find_filenames(thefolder, thename)

set value of cell this_rows_last_cell_index of selection range to foundfilenames

set this_rows_first_cell_index to this_rows_first_cell_index + range_column_count

set this_rows_last_cell_index to this_rows_last_cell_index + range_column_count

if this_rows_last_cell_index > (count of every cell of selection range) then exit repeat

end repeat

end tell

end tell

end tell

end tell

on find_filenames(thefolder, filename_start)

-- THIS SEARCHES FILES STARTING WITH A SPECIFIC STRING IN THEIR NAMES AND OUTPUTS JUST THEIR FILENAMES

-- IS SEARCHES IN THEFOLDER AND ALL SUB-DIRECTORIES

set theoutput to do shell script "cd " & thefolder & ";find " & "." & " -iname \"" & filename_start & "*\""

if theoutput ≠ "" then

set theoutput to every paragraph of theoutput

--OPTIONAL REMOVE THE FIRST CHARACTER OF EACH PATH

set tmp to {}

repeat with t in theoutput

set tmp to tmp & {(characters 2 through -1 of t) as text}

end repeat

set theoutput to tmp

set AppleScript's text item delimiters to "; "

set theoutput to theoutput as text

set AppleScript's text item delimiters to ""

end if

return theoutput

end find_filenames

--hubionmac.com 07.02.2005

--#################################--Preferences--#################################--

property daycount : 4

property depth_scan_switch : "off" --(on/off)

property dirname_in_aliasname : "off" --(on/off)

--###########################################################################--

global maxfolderdeep, folderkind, destination_folder, current_folder_name, tempfolder

--## Set all working directories

tell application "Finder"

set folderkind to kind of folder 1 of startup disk

try

set aliasfolder to (folder "recent_uploads_aliases" of startup disk) as alias

on error

make new folder at startup disk with properties {name:"recent_uploads_aliases"}

set aliasfolder to (folder "recent_uploads_aliases" of startup disk) as alias

--error "A folder called \"recent_uploads_aliases\" has been created at your startup disk."

end try

try

set temp_folder to folder "_temp" of aliasfolder as alias

set tempfolder to POSIX path of temp_folder

on error

make new folder at (aliasfolder as alias) with properties {name:"_temp"}

set temp_folder to folder "_temp" of aliasfolder as alias

set tempfolder to POSIX path of temp_folder

end try

set scan_group_folders to every folder of (aliasfolder as alias)

end tell

--## Now scan every folder

repeat with current_scan_group_folder in scan_group_folders

tell application "Finder" to set itemname to name of current_scan_group_folder

if itemname as text ≠ "_temp" then

--## clean the tempdir and the destination folder from aliases and links

tell application "Finder" to set destination_folder to original item of alias file "destination_folder" of current_scan_group_folder

do shell script "rm -f " & quoted form of (POSIX path of (destination_folder as alias)) & "*"

do shell script "rm -f " & quoted form of tempfolder & "*"

tell application "Finder" to set the_folders to every alias file of current_scan_group_folder

repeat with the_folder in the_folders

if name of the_folder ≠ "destination_folder" then

tell application "Finder" to set thepath to original item of the_folder

if depth_scan_switch = "on" then

set maxfolderdeep to (character 1 of ((name of the_folder) as text)) as integer

else

set maxfolderdeep to 1

end if

tell application "Finder" to set thefolder to original item of (the_folder as alias)

set current_folder_name to (name of thefolder) as text

make_sym_links(thepath)

end if

end repeat

-- ## create aliases of symbolic links at the destination directory

tell application "Finder"

set these_ to every item of temp_folder

repeat with this_ in these_

if dirname_in_aliasname = "on" then

set name_01 to name of container of (original item of this_)

set name_00 to name of (original item of this_)

set aliasname to name_00 & " @ " & name_01 as string

make new alias file to ((original item of this_) as alias) with properties {name:aliasname} at destination_folder

else

make new alias file to ((original item of this_) as alias) at destination_folder

end if

end repeat

end tell

end if

end repeat

on make_sym_links(the_folder)

set thepath to POSIX path of (the_folder as alias)

do shell script "find " & quoted form of thepath & " -ctime -" & daycount & " -maxdepth " & maxfolderdeep & " -mindepth " & maxfolderdeep & " -exec ln -s {} " & quoted form of tempfolder & " \\;"

end make_sym_links